// zantaLL.txt v1.0 (based off of basicnpc.txt)
// M. G. Slack - 2009
// (slack at attglobal dot net)
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.  Adds a special ability suite
// when in attack mode (based on abilnpc.txt).
//
// Duplicate of zanta.txt with some modifications for lower level parties.
// Originally had a check against another sdf, but wanted to remove so
// balancing happens in one place.
//
// *** NOTE *** Uses/checks sdf(2, 1) to force conversation.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i, target, last_used, whch, j;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME, 0);
	// set so special ability won't be used right from the start
	last_used = get_current_tick();
break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1), get_memory_cell(2), 1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
		else set_target(ME, -1);
	}

	// Look for a target, attack it if visible
	if (select_target(ME, 8, 0)) {
		do_attack();
		set_state(3);
	}

	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME, who_hit_me());
		do_attack();
		set_state(3);
	}

	if (get_flag(2, 1) > 0) {
		// Otherwise, just peacefully move around. Go back to start, if I'm too far
		// from where I started.
		if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
			if (get_ran(1, 1, 100) < 40)
				return_to_start(ME, 1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME, 25);
		}
	}
	else {
		begin_talk_mode(get_memory_cell(3));
	}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);

	// kick off special ability?
	if ((tick_difference(last_used, get_current_tick()) >= 5) &&
	    (get_ran(1, 1, 100) <= 20) && (can_see_char(1000))) {
		whch = get_ran(1, 0, 5);
		if (whch == 0) {
			print_named_str(ME, "throws a few explosive tablets.");
			damage_char(1000, get_ran(1, 1, 20), 4);
		}
		else {
			j = 0;
			while (j < 4) {
				if (char_ok(j) == TRUE) {
					put_jagged_zap(my_loc_x(), my_loc_y(), char_loc_x(j), char_loc_y(j), 3);
				}
				j = j + 1;
			}
			if (whch == 1) {
				print_named_str(ME, "fires draining beams.");
				run_animation_sound(65);
				set_char_status(1000, 1, -5, 0, 1);
			}
			else if (whch == 2) {
				print_named_str(ME, "fires weakening beams.");
				run_animation_sound(46);
				set_char_status(1000, 2, -5, 0, 1);
			}
			else if (whch == 3) {
				print_named_str(ME, "fires slowing beams.");
				run_animation_sound(7);
				set_char_status(1000, 3, -5, 0, 1);
			}
			else if (whch == 4) {
				print_named_str(ME, "fires charm rays.");
				run_animation_sound(60);
				set_char_status(1000, 8, 5, 0, 1);
			}
			else { // whch == 5
				print_named_str(ME, "fires sleeping rays.");
				run_animation_sound(89);
				set_char_status(1000, 10, 5, 0, 1);
			}
		}
		last_used = get_current_tick();
	}

	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
	}
	begin_talk_mode(get_memory_cell(3));
break;
